bbe2128abe
Includes: - inform ns3 user cmake was not found, or an unsupported version was found - replace open-mpi environment variables with command-line arguments - mark more variables as advanced - add -v and --verbose option to run and only output the programs output by default - fix scratch subdir prefixes and add tests - prevent cmake crash when scratch sources do not have a main function - disable MPI module by default - wrap cmakelists_content in quotes to prevent failure of filter_libraries - install pkgconfig files and add tests - pkg-config generation (still missing installation) - forward PYTHONPATH to modulegen - fix dependency search for brite, click and openflow
85 lines
2.6 KiB
CMake
85 lines
2.6 KiB
CMake
set(target_prefix scratch_)
|
|
|
|
function(create_scratch source_files)
|
|
# Return early if no sources in the subdirectory
|
|
list(LENGTH source_files number_sources)
|
|
if(number_sources EQUAL 0)
|
|
return()
|
|
endif()
|
|
|
|
# If the scratch has more than a source file, we need to find the source with
|
|
# the main function
|
|
set(scratch_src)
|
|
foreach(source_file ${source_files})
|
|
file(READ ${source_file} source_file_contents)
|
|
string(REGEX MATCHALL "main[(| (]" main_position "${source_file_contents}")
|
|
if(CMAKE_MATCH_0)
|
|
set(scratch_src ${source_file})
|
|
endif()
|
|
endforeach()
|
|
|
|
if(NOT scratch_src)
|
|
return()
|
|
endif()
|
|
|
|
# Get parent directory name
|
|
get_filename_component(scratch_dirname ${scratch_src} DIRECTORY)
|
|
string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}" "" scratch_dirname
|
|
"${scratch_dirname}"
|
|
)
|
|
string(REPLACE "/" "_" scratch_dirname "${scratch_dirname}")
|
|
|
|
# Get source name
|
|
get_filename_component(scratch_name ${scratch_src} NAME_WE)
|
|
|
|
set(target_prefix scratch_)
|
|
if(scratch_dirname)
|
|
# Join the names together if dirname is not the scratch folder
|
|
set(target_prefix scratch${scratch_dirname}_)
|
|
endif()
|
|
|
|
# Get source absolute path and transform into relative path
|
|
get_filename_component(scratch_absolute_directory ${scratch_src} DIRECTORY)
|
|
string(REPLACE "${PROJECT_SOURCE_DIR}" "${CMAKE_OUTPUT_DIRECTORY}"
|
|
scratch_directory ${scratch_absolute_directory}
|
|
)
|
|
add_executable(${target_prefix}${scratch_name} "${source_files}")
|
|
if(${NS3_STATIC})
|
|
target_link_libraries(
|
|
${target_prefix}${scratch_name} ${LIB_AS_NEEDED_PRE_STATIC}
|
|
${lib-ns3-static}
|
|
)
|
|
else()
|
|
target_link_libraries(
|
|
${target_prefix}${scratch_name} "${ns3-libs}" "${ns3-contrib-libs}"
|
|
"${ns3-external-libs}"
|
|
)
|
|
endif()
|
|
set_runtime_outputdirectory(
|
|
${scratch_name} ${scratch_directory}/ ${target_prefix}
|
|
)
|
|
endfunction()
|
|
|
|
# Scan *.cc files in ns-3-dev/scratch and build a target for each
|
|
file(GLOB single_source_file_scratches ${CMAKE_CURRENT_SOURCE_DIR}/*.cc)
|
|
foreach(scratch_src ${single_source_file_scratches})
|
|
create_scratch(${scratch_src})
|
|
endforeach()
|
|
|
|
# Scan *.cc files in ns-3-dev/scratch subdirectories and build a target for each
|
|
# subdirectory
|
|
file(GLOB_RECURSE scratch_subdirectories LIST_DIRECTORIES true
|
|
${CMAKE_CURRENT_SOURCE_DIR}/**
|
|
)
|
|
# Filter out files
|
|
foreach(entry ${scratch_subdirectories})
|
|
if(NOT (IS_DIRECTORY ${entry}))
|
|
list(REMOVE_ITEM scratch_subdirectories ${entry})
|
|
endif()
|
|
endforeach()
|
|
|
|
foreach(subdir ${scratch_subdirectories})
|
|
file(GLOB scratch_sources ${subdir}/*.cc)
|
|
create_scratch("${scratch_sources}")
|
|
endforeach()
|